Sổ Tay Số

Hàm IF nhiều điều kiện trong Excel: IF lồng, IFS, AND/OR

Cách dùng hàm IF trong Excel từ cơ bản đến IF nhiều điều kiện, IF 3 điều kiện, IF lồng nhau, hàm IFS và kết hợp AND, OR, kèm ví dụ bảng lương, điểm thi.

Hàm Excel & Google Sheets Cơ bản 8 phút đọc Cập nhật Biên soạn:

Hàm IF trả về một giá trị nếu điều kiện đúng và giá trị khác nếu điều kiện sai. Muốn kiểm tra nhiều điều kiện, bạn có ba cách: lồng nhiều IF vào nhau, dùng hàm IFS (Excel 2019, Microsoft 365, Google Sheets), hoặc ghép IF với AND/OR khi các điều kiện phải xét cùng lúc.

Cú pháp hàm IF

=IF(logical_test, value_if_true, value_if_false)
Đối sốÝ nghĩa
logical_testBiểu thức trả về TRUE/FALSE, ví dụ B2>=5, C2="Nam"
value_if_trueKết quả khi điều kiện đúng (số, chữ trong ngoặc kép, hoặc công thức khác)
value_if_falseKết quả khi điều kiện sai; bỏ trống thì Excel trả về FALSE

Ví dụ đơn giản: điểm ở B2 từ 5 trở lên thì “Đạt”, ngược lại “Không đạt”:

=IF(B2>=5, "Đạt", "Không đạt")
Lưu ý dấu phân cáchNếu máy đặt vùng Việt Nam (dấu phẩy là dấu thập phân), Excel dùng dấu chấm phẩy: =IF(B2>=5; "Đạt"; "Không đạt"). Gõ dấu phẩy mà Excel báo lỗi công thức thì đổi sang ;. Xem thêm cách đổi dấu phẩy, dấu chấm trong Excel.

IF 3 điều kiện: lồng IF vào nhau

Khi có nhiều mức, đặt một IF khác vào vị trí value_if_false. Ví dụ xếp loại theo điểm trung bình ở D2:

=IF(D2>=8, "Giỏi", IF(D2>=6.5, "Khá", IF(D2>=5, "Trung bình", "Yếu")))

Excel xét lần lượt từ trái sang phải và dừng ở điều kiện đúng đầu tiên. Vì vậy hãy sắp ngưỡng từ cao xuống thấp (hoặc thấp lên cao với dấu <), nếu viết lộn xộn kết quả sẽ sai mà không báo lỗi. Số dấu đóng ngoặc ở cuối bằng số hàm IF.

Hàm IFS: gọn hơn IF lồng

=IFS(D2>=8, "Giỏi", D2>=6.5, "Khá", D2>=5, "Trung bình", TRUE, "Yếu")

IFS nhận từng cặp điều kiện, kết quả. Cặp cuối dùng TRUE làm “trường hợp còn lại”; nếu thiếu, ô không khớp điều kiện nào sẽ báo #N/A. IFS có trong Excel 2019, 2021, 2024, Microsoft 365 và Google Sheets; Excel 2016 trở về trước không có, file mở trên máy cũ sẽ hiện #NAME?.

Với bảng có nhiều mức (trên 4–5 mức), dùng bảng tra và VLOOKUP gần đúng sẽ dễ sửa hơn, xem hàm xếp loại học lực.

Kết hợp IF với AND, OR

AND đúng khi tất cả điều kiện đúng; OR đúng khi ít nhất một điều kiện đúng.

Ví dụ 1: thưởng chuyên cần

Nhân viên đi làm đủ 26 công (C2) và không đi muộn lần nào (D2) được thưởng 500.000 đ:

=IF(AND(C2>=26, D2=0), 500000, 0)

Ví dụ 2: phụ cấp theo chức vụ

Trưởng phòng hoặc phó phòng được phụ cấp 1.000.000 đ:

=IF(OR(B2="Trưởng phòng", B2="Phó phòng"), 1000000, 0)

Ví dụ 3: phí vận chuyển đơn hàng

Đơn từ 500.000 đ (E2) hoặc khách nội thành (F2 = “Nội thành”) được miễn phí ship, còn lại 30.000 đ:

=IF(OR(E2>=500000, F2="Nội thành"), 0, 30000)

Ví dụ 4: điều kiện trong khoảng

Kiểm tra điểm nằm trong khoảng 5 đến dưới 6,5 không thể viết 5<=D2<6.5 như toán học; phải viết AND(D2>=5, D2<6.5).

Lỗi hay gặp với hàm IF

  • Quên ngoặc kép cho chữ: =IF(B2>=5, Đạt, ...) báo #NAME?. Chữ luôn nằm trong "...", số thì không.
  • So sánh số dạng văn bản: số nhập từ phần mềm khác có thể là text, "8">=5 cho kết quả lạ. Kiểm tra bằng =ISNUMBER(B2) và chuyển đổi theo bài hàm TEXT, VALUE.
  • Sai thứ tự ngưỡng trong IF lồng như đã nói ở trên.
  • Ô trống bị tính là 0: học sinh chưa có điểm sẽ bị xếp “Yếu”. Thêm điều kiện đầu: =IF(D2="", "", IF(...)).
  • Dấu ngoặc kép cong khi chép công thức từ Word/Zalo: “ ” không được Excel hiểu, hãy gõ lại dấu " thẳng.

Trên Google Sheets và điện thoại

Google Sheets dùng cú pháp IF, IFS, AND, OR giống hệt Excel. Dấu phân cách phụ thuộc File → Settings → Locale: chọn Việt Nam thì dùng ;. Trên app Excel và Google Sheets cho điện thoại, bạn gõ công thức vào thanh công thức như bình thường; bàn phím ảo có sẵn hàng ký hiệu >, =, ".

MẹoCông thức IF dài khó đọc? Trong thanh công thức, nhấn Alt + Enter để xuống dòng giữa các IF, công thức vẫn chạy bình thường.
#hàm if#if nhiều điều kiện#hàm ifs#excel#google sheets

Bài viết liên quan

Zalo